Andrew Cooke | Contents | Latest | RSS | Twitter | Previous | Next

C[omp]ute

Welcome to my blog, which was once a mailing list of the same name and is still generated by mail. Please reply via the "comment" links.

Always interested in offers/projects/new ideas. Eclectic experience in fields like: numerical computing; Python web; Java enterprise; functional languages; GPGPU; SQL databases; etc. Based in Santiago, Chile; telecommute worldwide. CV; email.

Personal Projects

Lepl parser for Python.

Colorless Green.

Photography around Santiago.

SVG experiment.

Professional Portfolio

Calibration of seismometers.

Data access via web services.

Cache rewrite.

Extending OpenSSH.

C-ORM: docs, API.

Last 100 entries

[Link, Politics] Cubans + Ultrasonics; [Book, Link] Laurent Binet; VirtualBox; [Book, Link] No One's Ways; [Link] The Biggest Problem For Cyclists Is Bad Driving; [Computing] Doxygen, Sphinx, Breathe; [Admin] Brokw Recent Permalinks; [Bike, Chile] Buying Bearings in Santiago; [Computing, Opensuse] Upgrading to 42.3; [Link, Physics] First Support for a Physics Theory of Life; [Link, Bike] Peruvian Frame Maker; [Link] Awesome Game Theory Tit-For-Tat Thing; [Food, Review] La Fabbrica - Good Italian Food In Santiago; [Link, Programming] MySQL UTF8 Broken; [Link, Books] Latin American Authors; [Link, Computing] Optimizatin Puzzle; [Link, Books, Politics] Orwell Prize; [Link] What the Hell Is Happening With Qatar?; [Link] Deep Learning + Virtual Tensor Machines; [Link] Scaled Composites: Largest Wingspan Ever; [Link] SCP Foundation; [Bike] Lessons From 2 Leading 2 Trailing; [Link] Veg Restaurants in Santiago; [Link] List of Contemporary Latin American Authors; [Bike] FTHR; [Link] Whoa - NSA Reduces Collection (of US Residents); [Link] Red Bull's Breitbart; [Link] Linux Threads; [Link] Punycode; [Link] Bull / Girl Statues on Wall Street; [Link] Beautiful Chair Video; Update: Lower Pressures; [Link] Neat Python Exceptions; [Link] Fix for Windows 10 to Avoid Ads; [Link] Attacks on ZRTP; [Link] UK Jazz Invasion; [Review] Cuba; [Link] Aricle on Gender Reversal of US Presidential Debate; {OpenSuse] Fix for Network Offline in Updater Applet; [Link] Parkinson's Related to Gut Flora; Farellones Bike Park; [Meta] Tags; Update: Second Ride; Schwalbe Thunder Burt 2.1 v Continental X-King 2.4; Mountain Biking in Santiago; Books on Ethics; Security Fail from Command Driven Interface; Everything Old is New Again; Interesting Take on Trump's Lies; Chutney v6; References on Entropy; Amusing "Alexa.." broadcast; The Shame of Chile's Education System; Playing mp4 gifs in Firefox on Opensuses Leap 42.2; Concurrency at Microsoft; Globalisation: Uk -> Chile; OpenSuse 42.2 and Synaptics Touch-Pads; Even; Cherry Jam; Lebanese Writer Amin Maalouf; C++ - it's the language of the future; Learning From Trump; Chinese Writer Hu Fayun; And; Apricot Jam; Also; Excellent Article on USA Politics; Oh Metafilter; Prejudice Against The Rurals; Also, Zizek; Trump; Why Trump Won; Doxygen + Latex on CentOS 6; SMASH - Solve 5 Biggest Problems in Physics; Good article on racism, brexit, and social divides; Grandaddy are back!; Consciousness From Max Entropy; Democrats; Harvard Will Fix Black Poverty; Modelling Bicycle Wheels; Amusing Polling Outlier; If Labour keeps telling working class people...; Populism and Choice; Books on Defeat; Enrique Ferrari - Argentine Author; Transcript of German Scientists on Learning of Hiroshima; Calvert Journal; Owen Jones on Twitter; Possible Japanese Authors; Complex American Literature; Chutney v5; Weird Componentized Virus; Interesting Argentinian Author - Antonio Di Benedetto; Useful Thread on MetaPhysics; RAND on fighting online anarchy (2001); NSA Hacked; Very Good LRB Article on Brexit; Nussbaum on Anger; Tasting; Apple + Kiwi Jam; Hit Me

© 2006-2017 Andrew Cooke (site) / post authors (content).

Permute Fucntion (Scheme)

From: "andrew cooke" <andrew@...>

Date: Tue, 14 Aug 2007 22:53:01 -0400 (CLT)

":";exec snow -- "$0" "$@"

(package* permute/v1.0.0
  (provide: (define (permute lst))))

; generates a list of all permutations
; assumes all values in original list are unique (under equal?)
(define (permute lst)
  (case (length lst)
    ((0) '())
    ((1) (list lst))
    (else (flat-map (lambda (head)
                      (map (lambda (perm) (cons head perm))
                           (permute (except head lst))))
                    lst))))

(define (flat-map f lst) (flat-map-acc f lst '()))
(define (flat-map-acc f lst acc)
  (if (null? lst)
      acc
      (flat-map-acc f (cdr lst) (append acc (f (car lst))))))

; this does not attempt to keep any kind of ordering
(define (except x lst) (except-acc x lst '()))
(define (except-acc x lst acc)
  (if (null? lst)
      acc
      (let ((head (car lst))
            (tail (cdr lst)))
        (if (equal? x head)
            (append acc tail)
            (except-acc x tail (cons head acc))))))


(test*
 (define (dup x) (list x x))
 (expect* (equal? '() (flat-map dup '())))
 (expect* (equal? '(1 1) (flat-map dup '(1))))
 (expect* (equal? '(1 1 2 2) (flat-map dup '(1 2)))))

(test*
 (expect* (equal? '() (except 0 '())))
 (expect* (equal? '() (except 1 '(1))))
 (expect* (equal? '(2) (except 1 '(1 2))))
 (expect* (equal? '(3 2 1) (except 0 '(1 2 3))))
 (expect* (equal? '(2 3) (except 1 '(1 2 3))))
 (expect* (equal? '(1 3) (except 2 '(1 2 3))))
 (expect* (equal? '(2 1) (except 3 '(1 2 3)))))

(test*
 (expect* (equal? '() (permute '())))
 (expect* (equal? '((1)) (permute '(1))))
 (expect* (equal? '((1 2)(2 1)) (permute '(1 2))))
 (expect* (equal? '((1 2 3)(1 3 2)(2 1 3)(2 3 1)(3 2 1)(3 1 2))
                  (permute '(1 2 3)))))

Improved Permutation Function (Start of List Library)

From: "andrew cooke" <andrew@...>

Date: Wed, 15 Aug 2007 12:07:38 -0400 (CLT)

":";exec snow -- "$0" "$@"

; library of list-related functions

(package* ac-lists/v1.0.0
  (provide:
      ; abstract the typical patter used to recurse over lists
      (define-syntax acl-list-process
        (syntax-rules (null?)
          ((_ ((null? list) null-body)
              ((head tail) body))
           (if (null? list)
               null-body
               (let ((head (car list))
                     (tail (cdr list)))
                 body)))))
    (define (acl-filter pred lst))
    (define (acl-filter-acc pred lst acc))
    (define (acl-except x lst))
    (define (acl-flat-map fun lst))
    (define (acl-flat-map-acc fun lst acc))
    (define (acl-permute lst))
    ))

; remove all values that match predicate from a list
(define (acl-filter pred lst) (reverse (acl-filter-acc pred lst '())))
(define (acl-filter-acc pred lst acc)
  (acl-list-process
   ((null? lst) acc)
   ((head tail) (if (pred head)
                    (acl-filter-acc pred tail acc)
                    (acl-filter-acc pred tail (cons head acc))))))

(test*
 (define (one? x) (= 1 x))
 (expect* (equal? '() (acl-filter one? '())))
 (expect* (equal? '() (acl-filter one? '(1))))
 (expect* (equal? '(2) (acl-filter one? '(2))))
 (expect* (equal? '(2 3) (acl-filter one? '(2 1 3)))))

; exclude instances of a particular value
(define (acl-except x lst) (acl-filter (lambda (y) (equal? x y)) lst))

(test*
 (expect* (equal? '() (acl-except 0 '())))
 (expect* (equal? '() (acl-except 1 '(1))))
 (expect* (equal? '(2) (acl-except 1 '(1 2))))
 (expect* (equal? '(1 2 3) (acl-except 0 '(1 2 3)))))

; map with append instead of cons
(define (acl-flat-map fun lst) (reverse (acl-flat-map-acc fun lst '())))
(define (acl-flat-map-acc fun lst acc)
  (acl-list-process
   ((null? lst) acc)
   ((head tail) (acl-flat-map-acc fun tail (append (fun head) acc)))))

(test*
 (define (dup x) (list x x))
 (expect* (equal? '() (acl-flat-map dup '())))
 (expect* (equal? '(1 1) (acl-flat-map dup '(1))))
 (expect* (equal? '(1 1 2 2) (acl-flat-map dup '(1 2)))))

; a list of all permutations
; assumes all values in original list are unique (under equal?)
(define (acl-permute lst)
  (define (perm-rest x)
    (define (cons-x rest) (cons x rest))
    (let ((rest (acl-except x lst)))
      (map cons-x (acl-permute rest))))
  (acl-list-process
   ((null? lst) '())
   ((head tail) (if (null? tail)
                    (list lst)
                    (acl-flat-map perm-rest lst)))))

(test*
 (expect* (equal? '() (acl-permute '())))
 (expect* (equal? '((1)) (acl-permute '(1))))
 (expect* (equal? '((1 2)(2 1)) (acl-permute '(1 2))))
 (expect* (equal? '((1 3 2)(1 2 3)(2 3 1)(2 1 3)(3 2 1)(3 1 2))
                  (acl-permute '(1 2 3)))))

Comment on this post